Lazarus free pascal - Bir bulmacanın anatomisi

 

Resimde görülen bulmacanın son bulduğu, tebrikler mesajının geldiği penceredir. Kodları wiki sayfasından alıp, küçük bir ekleme yaptım. Tabii, bulmaca bahane maksat dili öğrenmek.. Amaç, resimdeki gibi 15 butonu sıralamak.. Oyun başladığında butonlar karışmış şekilde geliyor. Dikkat ettiysen, resimde bir butonluk boşluk var. Oynarken, boşluğa komşu olan bir butona tıklayınca, o buton boşluk ile yer değiştiriyor. Diğer bir ifadeyle buton, kayıyor (sliding puzzle).

Yeni bir Application (form uygulaması) açtıktan sonra File > New Unit ile yeni unit2'yi projeye ekliyoruz. Save All yaparken unit2'nin ismini unitGameBoard.pas olarak değiştiriyoruz. Daha sonra unit1 içinde uses satırına unitGameBoard yazarak bu unit'i kullanıyoruz. Amaç, proje kodlarını farklı dosyalarda tutarak daha sistemli bir şekilde yazılım geliştirmek..

Bu programdan ne öğreneceğim dersen.. Kullanılan butonlar dinamik olarak oluşturuluyor. Yani komponent paletinden bir buton alıp, forma yerleştirmiyoruz. Butonların konumlarını, ve tıklayınca ne olacağını veya olmayacağını, hepsini yazılımda tanımlamış oluyoruz. Ayrıca, TGameBoard sınıfı (class) oluşturuluyor. Ve bu sınıf, ana programda (unit1) kullanılıyor. Bulmacanın çözüldüğünü anlamak için aşağıdaki koda, Success fonksiyonu, tarafımdan eklenmiştir.

unitGameBoard.pas :

unit unitGameBoard;

{$mode ObjFPC}{$H+}

interface

uses
  Classes, SysUtils;

const
  //bulmacayı basitleştirmek için sabitlere, yorumdaki değerleri girin
  GB_MAX_BUTTONS = 15; // 8
  GB_MAX_X = 4;        // 3
  GB_MAX_Y = 4;        // 3
  GB_EMPTY_PLACE ='-';
type

  { TGameBoard }

  TGameBoard = class
  private
     GameArray:array[1..GB_MAX_X, 1..GB_MAX_Y] of string;
     function ValidPoint(a_point:TPoint):boolean;
  public
    constructor Create;
    function ButtonPlace(a_name:string):TPoint;
    function CanMove(a_name:string):Boolean;
    function Change(a_name: string):TPoint;
    function Success:Boolean;
    procedure RandomArray;
    destructor Destroy; override;
  end;

implementation

function TGameBoard.ValidPoint(a_point: TPoint): boolean;
begin
  result := true;
  if a_point.y > GB_MAX_Y then result := false;
  if a_point.x > GB_MAX_X then result := false;
  if a_point.y < 1 then result := false;
  if a_point.x < 1 then result := false;
end;

constructor TGameBoard.Create;
var
  i, x, y : integer;
begin
  i := 1;
  for y := 1 to  GB_MAX_Y do
    for x := 1 to GB_MAX_X do
      begin
        if i < GB_MAX_BUTTONS+1
          then GameArray[x,y] := IntToStr(i)
          else GameArray[x,y] := GB_EMPTY_PLACE;
        inc(i);
      end;
  RandomArray;
end;

function TGameBoard.Success: Boolean;
var
  i, x, y : integer;
begin
  i := 1;
  result := true;
  for y := 1 to  GB_MAX_Y do
      for x := 1 to GB_MAX_X do
        begin
          if (i <= GB_MAX_BUTTONS) and (GameArray[x,y] <> IntToStr(i))
            then exit(False);
          inc(i);
        end;
end;

function TGameBoard.ButtonPlace(a_name: string): TPoint;
var
  x,y:integer;
begin
  result.x := 0;
  result.y := 0;
  for y := 1 to  GB_MAX_Y do
    for x := 1 to GB_MAX_X do
      if  GameArray[x,y] = a_name then
      begin
        result.x := x;
        result.y := y;
      end;
end;

function TGameBoard.CanMove(a_name: string): Boolean;
var
  empty, point:TPoint;
begin
  result := false;
  empty := ButtonPlace( GB_EMPTY_PLACE );
  point := ButtonPlace(a_name);
  if (abs(empty.x-point.x)=1) and (empty.y=point.y) then result := true;
  if (abs(empty.y-point.y)=1) and (empty.x=point.x) then result := true;
end;

function TGameBoard.Change(a_name: string): TPoint;
var
  empty, point:TPoint;
begin
  empty := ButtonPlace( GB_EMPTY_PLACE );
  result := empty;
  point := ButtonPlace(a_name);
  GameArray[point.x, point.y] := '-';
  GameArray[empty.x, empty.y] := a_name;
end;

procedure TGameBoard.RandomArray;
var
   j,i:integer;
   name:string;
   point,point2:TPoint;
begin
  for i := 0 to 1000 do
    begin
      j := random(4);
      point := ButtonPlace( GB_EMPTY_PLACE );
      point2 := point;
      case j of
        0: point2.x := point.x-1;
        1: point2.x := point.x+1;
        2: point2.y := point.y-1;
        3: point2.y := point.y+1;
      end;
      if ValidPoint( point2 ) then
        begin
           name :=  GameArray[point2.x, point2.y];
           GameArray[point.x, point.y] := name;
           GameArray[point2.x, point2.y] := GB_EMPTY_PLACE;
        end;
    end;
end;

destructor TGameBoard.Destroy;
begin
  inherited Destroy;
end;

end.

type'ın altında sınıf ve onun değişkenlerinin, prosedürlerinin imzaları yazılıyor. İmza, kısa hali demek oluyor. Prosedür veya fonksiyonların uzun halleri implementation'ın altına yazılıyor. Ana programda, TGameBoard.Create komutu kullanılınca yukarıda bulunan constructor işlemleri yapılmaktadır. GameArray (2 boyutlu dizi) doldurulup, butonların yerlerini karıştıran RandomArray prosedürü çağırılıyor. ButtonPlace, butonun konumunu geri döndürüyor. CanMove, butonun hareket edip edemeyeceğini true veya false olarak geri döndürüyor. Buton, boşluğun komşusu değilse hareket edemez. Change fonksiyonu, buton ve boşluğun yerlerini değiştiriyor. Program, algoritma olarak cidden zor. Amacım, algoritmalara takılmadan program yapısını incelemek zaten. 

Bulmacayı çözme işi, epey zor. Şahsen basitleşmiş halini çözebildim. Basit halini görmek için yukarıda const (sabitler) altında gerekli tüyoyu verdim.

unit1.pas (ana program) :

unit Unit1;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils, Forms, Controls, Graphics, Dialogs,
  StdCtrls,
  unitGameBoard;

type

  { TForm1 }

  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    Puzzle15:TGameBoard;
    procedure aButtonClick(Sender: TObject);
  public

  end;

var
  Form1: TForm1;

implementation

{$R *.lfm}

{ TForm1 }

procedure TForm1.FormCreate(Sender: TObject);
var
  i : Integer;
  aButton: TButton;
  point:TPoint;
begin
  Randomize;
  Puzzle15:= TGameBoard.Create;
  i := 1;
  while i <= GB_MAX_BUTTONS do
    begin                              //create 15 Buttons
      aButton:=TButton.Create(Self);   //create Button, Owner is Form1, where the button is released later
      aButton.Parent:=Self;            //determine where it is to be displayed
      aButton.Caption:=IntToStr(i);    //Captions of the buttons
      aButton.Width:=aButton.Height;   //Width should correspond to the height of the buttons
      point := Puzzle15.ButtonPlace(aButton.Caption);
      aButton.Left:= point.x* aButton.Width;    //Distance from left
      aButton.Top := point.y* aButton.Height;

      aButton.OnClick:=@aButtonClick; //the event handler for the button -> will be created yet
      inc(i);
    end;
  Self.Height:=aButton.Height*6;      //Height of the form should correspond to the height of the buttons
  Self.Width:=aButton.Width*6;        //Width of the form to match the width of all buttons
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  FreeAndNil(Puzzle15);
end;

procedure TForm1.aButtonClick(Sender: TObject);
var
  i:integer;
  point : TPoint;
begin
  if (Sender is TButton) and                     //called the event handler of a button out?
     TryStrToInt(TButton(Sender).Caption, i)       //then try to convert the label in a integer
    then
      begin
        if Puzzle15.CanMove(TButton(Sender).Caption) then
          begin
            point := Puzzle15.Change(TButton(Sender).Caption);
            TButton(Sender).Left:= point.x* TButton(Sender).Width;    //Distance from left
            TButton(Sender).Top := point.y* TButton(Sender).Height;
            //ShowMessage(IntToStr(point.x) + '-' + IntToStr(point.y));
          end;
      end;
  if Puzzle15.Success then
    begin
      ShowMessage('Congratulations !');
      Close;
    end;
end;

end.                  

Programda herşey bir butona tıklanması olayına bağlı olarak çalışıyor. Type'ın altına aButtonClick prosedürünün imzasını yazdıktan sonra aynı satırdayken Ctrl+Shift+C tuşlarına bastığımızda, aşağıda aButtonClick prosedürü otomatik olarak yazılacaktır. 

Form açıldığında bir kez çalışan FormCreate prosedürü içinde, aButton.OnClick:=@aButtonClick satırı yazmaktadır. Buradaki @ işareti, buton tıklandığında çalışacak olan prosedürün hafızadaki (ram) adresini ifade eder. Hangi butona tıklanırsa hep bu prosedür çalışacaktır. Tbutton(Sender), tıklanan butonu ifade etmektedir. Görüldüğü gibi yukarıdan aşağıya sırasıyla uses, type (tip), var, implementation (işin yapılması) işlemleri her iki unit'de de aynı sıralamaya sahip. Her pascal programında olduğu gibi olaylar, prosedürler ve fonksiyonlar, implementation kelimesinden sonra yazılıyor.